class SheepArmedPedestrianGenerator extends Actor;

struct InventoryItem  {
   var() class<Inventory> Inventory;
   var() int              Count;
};

struct InitialAllianceInfo  {
   var() Name  AllianceName;
   var() float AllianceLevel;
   var() bool  bPermanent;
};

var(Pedestrian) int NumPedestrians; //max 32
var(pedestrian) bool bUseSpawnLimit; //should this generator use the threshold stuff?
var(pedestrian) int Spawnlimit;  //threshold for respawn, if set to numpedestrians-1, it'll bump up numbers after only a single death, if set to 0, requires all spawned peds to die before respawning occurs
var(pedestrian) float Respawndelay; //how long it waits after a 'threshold' death to respawn pawns
var float respawntimer; //internal counter
var float counttime; //not sure if necessary, but can't playtest..such is life, eh?
var bool bSleeping; //internal block on respawning
var(Pedestrian) class<ScriptedPawn> PedClasses[8]; //classes to spawn, chosen randomly

var(SpawnLocation) bool bOutOfLOS; //if true, only spawn pedestrians when out of player's LOS
var(SpawnLocation) name AltSpawnTag; //if bOutOfLOS is true, and the generator is in player's LOS, use alternate SpawnPoints with this tag

var(Pedestrian) name PedOrders,PedOrdersTag;

var(Pedestrian) string PedBindName; //if not blank, will set the pedestrians' bind name to this
var(Pedestrian) string PedBarkBindName; //as above, for barks
var(pedestrian) bool bUseRandomNames; //generate random names from our list?
var(Pedestrian) string FirstNames[30]; //to allow random name generation
var(Pedestrian) string LastNames[30];
var(pedestrian) int MaxTotalPeds;
var(pedestrian) bool bSetMax;
var(pedInventory) bool bSetInventory;
var(pedInventory) InventoryItem PedInitialInventory[8];


var(PedAlliances) InitialAllianceInfo PedInitialAlliances[8];
var(pedAlliances) bool bSetAlliances;
var (pedAlliances) name PedAlliance;

var ScriptedPawn pedestrians[32];
var int numClasses; //number of classes
var int numFirstNames; //number of names
var int numLastNames;
var int numPedsSpawned;


function PostBeginPlay()
{
Super.PostBeginPlay();

if(PedClasses[0]==None)
   {
   Destroy();
   return;
   }
numPedsSpawned=0; //zero the count just in case

if(NumPedestrians>32) NumPedestrians=32;

if(bUseSpawnLimit)
   {
   if(Spawnlimit >= Numpedestrians)
      Spawnlimit = Numpedestrians-1;
   respawntimer=respawndelay;
   bSleeping=true;
   }
   

for(numClasses=0;(numClasses<8 && PedClasses[numClasses]!=None);numClasses++)
   {}

for(numFirstNames=0;(numFirstNames<30 && FirstNames[numFirstNames]!="");numFirstNames++)
   {}

for(numLastNames=0;(numLastNames<30 && LastNames[numLastNames]!="");numLastNames++)
   {}

SetTimer(1.0,True);
}

function Timer()
{
if(bSetMax && (numpedsspawned >= maxTotalPeds))
   {
   Destroy();
   return;
   }
if(GetNumPds() < NumPedestrians)
   {
   if(!bUseSpawnLimit)
      SpawnPed();
   else
      {
      if(GetNumPds() <= Spawnlimit && !bSleeping) //is our total number of peds at or below the threshold? And have we been here before?
         {
         bSleeping=true; //starts us sleeping
         respawntimer=0; //sets the internal clock
         }
      else if(bSleeping)
         {
         respawntimer+=counttime;
         if(respawntimer >= respawndelay)
            {
            if(GetNumPds() == (NumPedestrians-1)) //are we one below the total numpeds desired? Then spawn one and stop us sleeping.
               {
               SpawnPed();
               bSleeping=false;
               }
            else
               SpawnPed();
            }
         }
      else
         return; //nothing to do for now
      }
   }
            
         
}

function int GetNumPds() //returns the number of pedestrians
{
local int x,y;

y=0;

for(x=0;x<32;x++)
   {
   if(pedestrians[x]!=None)
      y++;
   }

return y;
}

function SpawnPed()
{
local int x;

for(x=0;(x<32 && pedestrians[x]!=None);x++)
   {}
if(x>=32) return; //no space for more peds

if(EstablishSpawnLoc()==vect(0,0,0)) //can't spawn at this time!!
   return;

pedestrians[x]=Spawn(PedClasses[Rand(numClasses+1)],self,,EstablishSpawnLoc());

if(pedestrians[x]==None)
   pedestrians[x]=Spawn(PedClasses[Rand(numClasses+1)],self,,EstablishSpawnLoc(True));

if(pedestrians[x]!=None && PedBindName!="")
   pedestrians[x].BindName=PedBindName;

if(pedestrians[x]!=None && PedBarkBindName!="")
   pedestrians[x].BarkBindName=PedBarkBindName;

if(pedestrians[x]!=None)
{
   if(bSetMax)
      numpedsSpawned++;
   if(bUseRandomNames)
   {
      pedestrians[x].FamiliarName=FirstNames[Rand(numFirstNames)]@LastNames[Rand(numLastNames)];
           pedestrians[x].UnfamiliarName=FamiliarName;
        }
}

if(pedestrians[x]!=None && PedOrders!='None')
   pedestrians[x].SetOrders(PedOrders,PedOrdersTag,True);
if(pedestrians[x] != none && bSetInventory)
    ArmPed(pedestrians[x]);
if(pedestrians[x] != none && bSetAlliances)
    AllyPed(pedestrians[x]);
}


function ArmPed(scriptedpawn ped)
{
local int i;
local scriptedpawn P;
local inventory Inv, invcheck;

P=ped;


if(P != none)
     {
    for (i=0;i<8;i++)
        {
        inv=P.FindInventoryType(P.InitialInventory[i].Inventory);
        //invcheck=pedInitialInventory[i];
        if(inv != none)    //get rid of anything already there
               {
               P.DeleteInventory(inv);
               Inv.Destroy();
               }
        //if(invcheck !=none)
        if(pedInitialInventory[i].Inventory !=none)
            {
            P.InitialInventory[i].Inventory=pedInitialInventory[i].Inventory;
            P.InitialInventory[i].Count=pedInitialInventory[i].Count;
            //if(invcheck.IsA('Ammo')
            //     P.InitialInventory[i].Count=NumClips;
            //else
            //    p.InitialInventory[i].Count=1;
            }
        }
        P.InitializeInventory();
    }
}

function AllyPed(scriptedpawn ped)
{
local int i;
local scriptedpawn P;


P=ped;

if(pedAlliance != '')
               P.Alliance=PedAlliance;

for (i=0; i<8; i++)
      if (PedInitialAlliances[i].AllianceName != '')
         P.ChangeAlly(PedInitialAlliances[i].AllianceName,
                    PedInitialAlliances[i].AllianceLevel,
                    PedInitialAlliances[i].bPermanent);



}



function Vector EstablishSpawnLoc(optional bool bUseAlt) //bUseAlt - if passed & true, use an alternate location
{
local SpawnPoint p;
local Vector v,v2;

if((bOutOfLOS && PlayerCanSeeMe()) || bUseAlt)
   {
   if(AltSpawnTag=='None')
      return Vect(0,0,0);

   foreach AllActors(class'SpawnPoint',p,AltSpawnTag)
      {
      if(p!=None)
         if( (!p.PlayerCanSeeMe()) || (bUseAlt && !bOutOfLOS))
            {
            v=p.Location;
            v-=(Vect(1,1,0) * p.CollisionRadius);
            v2=VRand(); v2.Z=0.0; v2=v2*2*p.CollisionRadius;
            return v+v2;
            }
      }
   }
else
   {
   v=Location;
   v-=(Vect(1,1,0) * CollisionRadius);
   v2=VRand(); v2.Z=0.0; v2=v2*2*CollisionRadius;
   return v+v2;
   }

return Vect(0,0,0);
}

defaultproperties
{
bHidden=True
NumPedestrians=8
MaxTotalPeds=50
bSetMax=false
counttime=1.00
RespawnDelay=300
Spawnlimit=0
PedClasses(0)=class'LowerClassMale'
PedClasses(1)=class'LowerClassMale2'
PedClasses(2)=class'LowerClassFemale'
bOutOfLOS=True
PedBindName=""
PedBarkBindName=""
bUseRandomNames=true
FirstNames(0)="Ashley"
LastNames(0)="Smith"
PedOrders=Wandering
CollisionRadius=64.0
}